Excelマクロによるコピー（転記）入門

2019年11月12日

URLをコピーしました！

「マクロ　コピペ」「マクロ　転記」で検索して当ブログをご覧いただいております。
Excelマクロでのコピー（転記）の基礎をまとめてみました。

※カフェにて　by　α6400

1 Excelマクロでコピー
2 Excelマクロで値（Value）のみ転記
3 コピペの繰り返し

Excelマクロでコピー

次のようなデータがあり、シート「4月」の日付（セルA2）をシート「data」のセルA2へコピーするとします。
（シート「4月」には、25行までデータが入っています）

人の手でやるなら、Ctrl＋Cで選択して、Ctrl＋Vで貼り付ければ済む話です。
しかしながら、それを繰り返さなければいけません。

もちろん、範囲をまとめて選択して、コピー、貼り付けをすることもできますが、シートが複数あったり、ファイルに分かれていたり、毎月、毎週、毎日やらなければいけないとなると大変です。

コピペだけで済む仕事はできるだけ自動化したいものであり、そのほうが人よりも速くて正確にできます。
人とパソコンの役割分担は、それぞれが得意なことをやるのが原則です。

Excelマクロでコピーをする場合、主に2つに方法があります。

その1つは、copyを使う方法。

こう書きます。

Sub copy()
　Worksheets("4月").Range("a2").copy Worksheets("data").Range("a2")
End Sub

それぞれ、このような意味です。

実行するとこうなります。

他のセルも同様に書けばいいのですが、それだと美しくありません。
まとめてコピーするなら、こう書きます。
セルA2からG25を、Range(“a2”, “g25”)と指定できるのです。

Sub copy()
　Worksheets("4月").Range("a2", "g25").copy Worksheets("data").Range("a2")
End Sub

このような意味になります。

結果はこうなりますが、色（書式）までコピーすると不便な場合もあるでしょう。

値のみを貼り付けるなら、こう書きます。

Sub copy_value()

　Worksheets("4月").Range("a2", "g25").copy
　Worksheets("data").Range("a2").PasteSpecial Paste:=xlPasteValues

End Sub

実行するとこうなり、データとしても扱いやすいです。

Excelマクロで値（Value）のみ転記

もう1つの方法は、値を入力する方法。

こう書きます。
シンプルに　＝　でつなぐだけです。

Sub value()
　Worksheets("data").Range("a2", "g25").value = Worksheets("4月").Range("a2", "g25").value
End Sub

意味はこうなります。
コピーのときと違い、シート「data」、「4月」の順で書きます。
〇＝△で、「〇に△を入れる」という意味ですので。

こちらのほうがシンプルで書きやすいです。
特に、1つのセルをコピーするときは、こちらのValueのほうがいいでしょう。

ただ、連続でデータをコピーする場合は、値のみコピーのほうがわかりやすいです。

私は、

・単独でコピー　Value

・複数範囲をコピー　値のみ貼り付け

と使っています。

コピペの繰り返し

これらコピペを繰り返すこともマクロではできます。

値のみコピーの場合

Sub copy_value_repeat()
'値のみコピー　繰り返し

    Dim W_s As Worksheet
    For Each W_s In Worksheets
    
        If W_s.Name <> "data" Then
            Dim Sheet_row
            Sheet_row = W_s.Range("a" & Rows.Count).End(xlUp).Row
            
            W_s.Range("a2", "g" & Sheet_row).copy
            
            Dim Data_row
            Data_row = Worksheets("data").Range("a" & Rows.Count).End(xlUp).Row
            
            Worksheets("data").Range("a" & Data_row + 1).PasteSpecial Paste:=xlPasteValues
        End If
    
    Next

End Sub

値を入力する場合

Sub value_repeat()
'値を入力　繰り返し

    Dim W_s As Worksheet
    For Each W_s In Worksheets
    
        If W_s.Name <> "data" Then
            Dim Sheet_row
            Sheet_row = W_s.Range("a" & Rows.Count).End(xlUp).Row
            
           
            Dim Data_row
            Data_row = Worksheets("data").Range("a" & Rows.Count).End(xlUp).Row
            
            
            Worksheets("data").Range("a" & Data_row + 1, "g" & Data_row - 1 + Sheet_row).value = W_s.Range("a2", "g" & Sheet_row).value
            
        End If
    
    Next

End Sub

値をコピーする方法（前者）で解説すると、4月、5月、6月のシートで繰り返し処理できるように、For Eachを使っていますが、シート「data」は除きたいので、IFで指定しています。
赤い部分がFor Each、黄色い部分がIFで、それぞれ、間にあるプログラムを処理するものです。